Android ワイヤレスデバッグ

携帯側の設定

[設定]-[システム]-<詳細設定>-[開発者向けオプション]を開く。

開発者向けオプション

デバッグの項目に「ワイヤレスデバッグ」という項目があるのでチェックをOnにする。

デバイスとのペア設定

「ワイヤレスデバッグ」を選択すると詳細画面が開くので、「ペア設定コードによるデバイスペア設定」を選択する。

ペアリングするための「IPアドレスとポート」と、「Wi-Fiペア設定コード」が表示される。

ワイヤレスデバッグ

「ワイヤレスデバッグ」では接続するための「IPアドレスとポート」が表示される。

 

接続コマンド

ペアリング

adb pair ペアリング用IPアドレス:ポート番号 Wi-Fiペア設定コード

「デバイスとのペア設定」に表示されているIPアドレスとポート番号を入力する。

「ワイヤレスデバッグ」に表示されているIPアドレスとポート番号ではない。

接続

adb connect 接続用IPアドレス:ポート番号

「ワイヤレスデバッグ」に表示されているIPアドレスとポート番号を入力する。

接続確認

adb devices

接続されているデバイスの一覧が表示される。

Tiling Noise

前回の草が揺れる風にノイズテクスチャを使っていたけど、uvのオフセットが端に行った時草の動きが激しくなる。草むらの中で動物が走ってるような感じ。

ノイズ画像を並べて見る

ノイズ画像を並べた時こんな感じになる。

ValueNoise

PerlinNoise

CellularNoise

VoroNoise

SimplexNoise

１枚の四角にUVを0～3で表示すると、３回ラップして表示される。

真ん中と隣接する絵がつながっていない。

ノイズ作成のパラメータには画像サイズとGridサイズを渡す。

画像サイズが256で、Gridサイズが64とすると、256÷64=４つ分のグリッドでノイズを生成する。

ノイズ関数は渡されたx,yを整数部分と小数部分に分解するが、この整数部分を画像サイズ÷Gridサイズの値でmodしてやるとつなぎ目がなくなる。

TilingValueNoise

TilingPerlinNoise

TilingCellularNoise

TilingVoroNoise

ただし、シンプレックスノイズだけはうまくいかない。

歪ませた三角形で処理するためmodが使えない。

Tiling Simplex Noise

ネット上でいくつかシンプレックスノイズを繋げる方法を見つけたが、うまく自分のソースに適用できなかった。

シンプレックスノイズは諦めようかと思った時、このサイトを見つけた。

４次元のシンプレックスノイズ関数を使って、縦と横にぐるっと回り込むように参照することで実現するようだ。

パラメータの指定方法などが現状とかなり違っていたので調整に時間がかかった。最初はシンプレックスノイズ単体でしか出来なくて、fBMを通すと同じように境目が出来てしまったんだけど、いろいろやっているうちにfBMを使ってもつながるようになった。

TilingSimplexNoise

Geometry Shader

今回はジオメトリシェーダについて。

GSを使うレンダリングパイプラインの経路は２パターンがある。

VS-GS-PS

VS-HS-DS-GS-PS

ジオメトリシェーダはVSから直接か、DS経由で呼ばれる。

前回やった距離に応じたテッセレーションの結果を元に、ジオメトリシェーダで草を生やしたいと思い準備を進めてきた。

発端はこの動画（動画１、動画２、動画３）

この動画では距離に関係なく細分化して草を生やして、近くと遠くでポリコン数が違う草を生やすということをしている。

そもそも草の生やし方がわからないので、まずはそこから。

Geometry Shaderの関数定義

関数の定義はこんな感じ。

	[maxvertexcount(「出力頂点数」)]
	void GSMain( 「プリミティブ」 GSInput In[「添字」], inout 「ストリーム」<GSOutput> Out )

出力頂点数

出力する頂点の最大数を指定する。

プリミティブ

point、line、triangle、lineadj、triangleadjが指定できる。

triangle以外は使い方を理解できていない。

添字

プリミティブに指定した型により決まる。

pointの時１、lineの時２、triangleの時３、lineadjの時４、triangleadjの時６。

ストリーム

プリミティブに指定した型により決まる。

pointの時PointStream、line、lineadjの時LineStream、triangle、triangleadjの時TriangleStream。

三角形を出力

GSInputで渡された点の１つを使って三角形を作ってみる。

	float3 pos = In[0].Pos.xyz ;

	GSOutput o[3] ;
	
	o[0].Pos = float4( pos + float3(  0.5f, 0.0f, 0.0f ), 1 ) ;
	o[1].Pos = float4( pos + float3( -0.5f, 0.0f, 0.0f ), 1 ) ;
	o[2].Pos = float4( pos + float3(  0.0f, 4.0f, 0.0f ), 1 ) ;

	o[0].Pos = mul( gCam.TransPV, o[0].Pos ) ;
	o[1].Pos = mul( gCam.TransPV, o[1].Pos ) ;
	o[2].Pos = mul( gCam.TransPV, o[2].Pos ) ;

	Out.Append( o[0] ) ;
	Out.Append( o[1] ) ;
	Out.Append( o[2] ) ;
	Out.RestartStrip() ;

posを基準として、左右に0.5ずつずらした点を底辺、上に4.0ずらした点を頂点とした。

頂点データの関して

前回のハルシェーダ、ドメインシェーダでは、今まで通り頂点シェーダでProjectionとView行列を掛けた頂点を使っていた。でもいろいろ見ていくと、どうやらHS～GSをやる場合は、VSでは変換せず、PS直前のシェーダで変換するのが普通みたい。

ジオメトリで出力すると、それまでの点は消えてしまうらしい。

ジオメトリでAppendした分だけが次のステージに進むということか。

テッセレータで近くの点を増やした場合もそのまま動作している。

ただ、横に回り込んで見ようとするとカリングされて消えてしまう。

ビルボード

ビルボードの仕組みを使えば、常にカメラの方を向くので消えないと思い色々調べてみた。

結構たくさん見つかって、ほとんどの方法がViewの逆行列を用意して移動部分の_41、_42、_43を０にして掛けるというもの。参考にしながらいろいろ試したけどうまくいかなかった。

ただ、今回やりたいことはカメラの向きに対して基準点を中心に回転させたいだけなので、自力で計算できるかもしれない。

カメラの位置と、基準点の位置のxとzの差分をatan2に渡すとラジアンが得られる。

これにsin、cosを使ってずらせば行けるはず。

	void BillboardGrass( in float3 pos, in float a, in float y, in float w, out float4 p1, out float4 p2 )
	{
		float x = -cos( a ) ;
		float z = sin( a ) ;
		p1.x = pos.x - x * w ;
		p1.z = pos.z - z * w ;
		p2.x = pos.x + x * w ;
		p2.z = pos.z + z * w ;
		p1.y = p2.y = pos.y + y ;
		p1.w = p2.w = 1.0f ;
	}

Excelで計算した結果、xに-cos、zにsinを足せばOKっぽい。

	GSOutput o[3] ;
	float a = atan2( pos.x - gCam.Eye.x, pos.z - gCam.Eye.z ) ;
	BillboardGrass( pos, a, 0.0f, 0.5f, o[0].Pos, o[1].Pos ) ;
	o[2].Pos = float4( pos + float3(  0.0f, 4.0f, 0.0f ), 1 ) ;

呼び元でatan2を呼んで、幅(半径0.5f)を指定すると常にカメラを向く状態で三角形を作り出すことが出来た。

草ポリゴン

ただの三角形から頂点を増やして草っぽくするために頂点を４つ増やす。

	GSOutput o[3] ;
	float a = atan2( pos.x - gCam.Eye.x, pos.z - gCam.Eye.z ) ;
	BillboardGrass( pos, a, 0.0f, 0.3f, o[0].Pos, o[1].Pos ) ;
	BillboardGrass( pos, a, 1.5f, 0.2f, o[2].Pos, o[3].Pos ) ;
	BillboardGrass( pos, a, 3.0f, 0.15f, o[4].Pos, o[5].Pos ) ;
	o[6].Pos = float4( pos + float3(  0.0f, 4.0f, 0.0f ), 1 ) ;

先程用意した関数を使って、４点追加する。

出力結果も想定通りになった。

ランダム要素

最初に用意した頂点は１１×１１の正方形で規則正しく並んだ状態。

テッセレータで細分化されたものを上から見てみると、こちらも規則正しく分割されている。

この状態では不自然なのでランダム要素を加えていろいろなものを補正しようと思う。

準備

２つのノイズテクスチャを用意する。

１つは単純なランダム要素がほしいのでホワイトノイズ。

２つ目はなめらかな状態がほしいので、フラクタルノイズがかかっているもの。ベースはなんでもいいんだけどシンプレックスノイズにしてみた。

ホワイトノイズを使って、xz位置の補正、草の高さの補正、色の補正をする。

xz位置の補正

	float ofs = TexRandNoise.SampleLevel( Sampler, uv, 0 ).r * 2.0f - 1.0f ;
	pos.x += ofs * 5.0f ;
	pos.z += ofs * 2.5f ;

ジオメトリシェーダではTextureのSampleが使えないのでSampleLevelで代用。

テクスチャの値と取り出し、-1～1の範囲に補正した値をofsに代入。

xzそれぞれにofsを足す。

草の高さの補正

	float oy = ( ofs * 1.0f ) ;
	BillboardGrass( pos, a, 0.0f, 0.3f, o[0].Pos, o[1].Pos ) ;
	BillboardGrass( pos, a, 1.5f+oy, 0.2f, o[2].Pos, o[3].Pos ) ;
	BillboardGrass( pos, a, 3.0f+oy, 0.15f, o[4].Pos, o[5].Pos ) ;
	o[6].Pos = float4( pos + float3( 0, 4.0f+oy, 0 ), 1 ) ;

高さ補正用のoyを2～6の点にそれぞれ足す。

色の補正

	o[0].UV = float2( 0.0f, 0.0f ) ;
	o[1].UV = float2( 1.0f, 0.0f ) ;
	o[2].UV = float2( 0.2f, 0.1f ) ;
	o[3].UV = float2( 0.8f, 0.1f ) ;
	o[4].UV = float2( 0.4f, 0.25f ) ;
	o[5].UV = float2( 0.6f, 0.25f ) ;
	o[6].UV = float2( 0.5f, 0.50f + ( ofs * 0.5 )) ;

設定していなかったuvを設定。 草の先端部分は長い場合黄色っぽく、短い場合は緑になるようにずらしておく。

	Out.Col = lerp( float4(0.20f + In.Type * 0.5f,0.40f,0.1f,1.0f ), float4(0.75f,1.0f,0.25f,1.0f ), In.UV.y ) ;

ピクセルシェーダを渡されたuvから色を算出するようにする。

D3D12_FILL_MODE_WIREFRAMEをD3D12_FILL_MODE_SOLIDに戻してレンダリングしたもの。

位置、高さがバラけて、先端の色も黄色っぽいのと緑が混在している感じになった。

風を吹かせる

今のところただまっすぐ突っ立ってるだけなので、風にそよいでいる感を出してみる。

用意したノイズテクスチャのもう１つを使う。

	float Wind = TexNoise.SampleLevel( Sampler, uv + gSP.Time*0.0005f, 0 ).r * 2.0f - 1.0f
	o[2].Pos.xz += Wind * 1.0f ;
	o[3].Pos.xz += Wind * 1.0f ;
	o[4].Pos.xz += Wind * 1.5f ;
	o[5].Pos.xz += Wind * 1.5f ;
	o[6].Pos.xz += Wind * 2.0f ;

gSP.Timeは定数バッファで、起動時からのFrame数が渡ってくる様にしてある。

これをuvのオフセットとして使い、毎フレーム少しずつずらした値をWindとして取得する。

底辺以外の頂点にWindを足す。掛け目は上の方ほど影響が大きくなるようにする。

遠くは手を抜く

カメラとの距離を測って、３つの表現方法に切り替えてみる。

手前は頂点７つ版、真ん中は頂点３つ版、奥はビルボードで草のテクスチャを貼り付ける。

位置により手を抜く

草テクスチャ

ジオメトリシェーダの出力構造体に「uint Type」を追加して、それぞれの識別番号を入れる。

ピクセルシェーダで識別番号をみて、ビルボードとそれ以外に分けて処理をする。

三角部分に赤みを足して見たのがこれ。

上から見下ろすとこんな感じ。

上からのカメラがある場合は使い物にならないけど、キャラクタ視点だけなら使えそう。

PIX結果

ハルシェーダのEdgeFactorを12.25でPIXのスナップショットを取ってみたところ、869.583usだった。1msかかってないので、なかなか優秀かも。

距離に応じたテッセレーション

前回の続き

細かくしてどうするのか？

テセレーションについて調べていく中で見つけたのが、ローポリゴンで作ったメッシュをカメラの距離に応じて細分化することにより、近くの場合は細かく詳細に、遠くの場合は荒くすることにより見た目とパフォーマンスを両立させることができるというもの。他にもいろいろ使用例があったけど、これが一番イメージが付きやすかった。

さっそくこれをやってみたい。

前回のプログラムでカメラとの距離に応じて係数を計算するようにしても頂点４つだけのメッシュでうまく反映されない。そこで頂点を１１×１１で四角が１００個（三角が２００個）分のデータを用意して描画してみた。

D3D_PRIMITIVE_TOPOLOGY_4_CONTROL_POINT_PATCHLIST

４頂点に対して、インデックスバッファを６個ずつで、１００個分四角を書いているつもりだけど、こんな表示になってしまう。

試しにトポロジを今までのトライアングルリストで描画してみる

D3D_PRIMITIVE_TOPOLOGY_TRIANGLELIST

正しく表示され頂点バッファ、インデックスバッファは問題ないみたいだ。

ここでふと思いつく。

トライアングルリストの場合はややこしくて、頂点０（左上）、頂点１（右上）、頂点２（左下）、頂点３（右下）の４頂点ある場合、インデックスバッファは(0,1,2),(3,2,1)というふうに、時計回りで３点ずつ２つの３角形で指定する。

コントロールポイントの場合は、そのポイントがどれかを単純に指定すればいいのではないか？

頂点データは同じで、インデックスバッファは(0,1,2,3)の４つ（D3D_PRIMITIVE_TOPOLOGY_4_CONTROL_POINT_PATCHLIST

の場合）を単純に指定すればどうか。

D3D_PRIMITIVE_TOPOLOGY_4_CONTROL_POINT_PATCHLIST修正版

正しく表示された。

うまく行ったけど、これってインデックスバッファの中身変えないと使えないのか？

いままでQuadでやっていたけどTriで確認したら、今までのインデックスバッファの指定方法で行けた。もしかしてTriしか使わないかも？

距離に応じたテセレーション

こんな関数を用意した。

	float DistanceTessellationFactor( float4 v, float min, float max, float t )
	{
		float d = distance( v.xyz, gCam.Eye.xyz ) ;
		return clamp( 1.0 - ( d - min ) / ( max - min ), 0.01, 1.0 ) * t ;
	}

カメラの位置と頂点の位置をdistanceに渡してその結果に掛け目を掛けて係数を返す。

#define MINDIST 50.0
#define MAXDIST 120.0
	float3 f ;
	f.x = DistanceTessellationFactor( IP[0].Pos, MINDIST, MAXDIST, gHSParam.EdgeFactor ) ;
	f.y = DistanceTessellationFactor( IP[1].Pos, MINDIST, MAXDIST, gHSParam.EdgeFactor ) ;
	f.z = DistanceTessellationFactor( IP[2].Pos, MINDIST, MAXDIST, gHSParam.EdgeFactor ) ;
	float3 a ;
	float b, c ;
	ProcessTriTessFactorsAvg( f, 1.0f, a, b, c ) ;
	Out.Edge[0] = a.x ;
	Out.Edge[1] = a.y ;
	Out.Edge[2] = a.z ;
	Out.Inside = b ;

Quadなら４つ分の係数を計算して、Process2DQuadTessFactorsAvgまたはProcessQuadTessFactorsAvgを呼び出す。

Triなら３つ分の係数を計算してProcessTriTessFactorsAvgを呼び出す。

それぞれInsideScaleは1.0fを指定しておけば、EdgeFactorに応じていい具合の値を返してくれる。(イマイチbとcの違いがわからず)

Tri版

Quad版

遠くはそのままで、近くは細分化されているのがわかる。

Tesselation(Hull Shader & Domain Shader)

３Dのプログラムを始める時、最初に説明されているのがグラフィックスパイプラインで、こんなフローを見ることになる。

Graphics Pipeline

最初に扱うのも今まで扱ってきたのもVSとPSのみ。VSだけっていうこともあった。

他のステージはよくわからないけどとりあえずそんなのもあるんだ程度で、もしかするとずっと使わないかもしれないと思ってた。

シェーダ以外の灰色の枠に関しては関与できず、パラメータを渡すのみ。

InputAssemblerに関しては、IAから始まる関数IASetPrimitiveTopology、IASetVertexBuffers、IASetIndexBufferを通して頂点バッファ、インデックスバッファを渡している。

今回の話題はTesselatoerの部分。

テッセレータ

頂点のデータをこのテッセレータが細かくしてくれるらしい。

どういうふうに細かくするかを決めるのがHull Shaderで、Hull Shaderの出力結果を使ってテッセレータが細かくする方針を立ててくれて、Domain Shaderで実際に決定する流れみたい。

だからテッセレータを使う場合はHSとDSはセットで用意する必要がある。

HSのみセットして実行すると怒られる。

D3D12 ERROR: ID3D12Device::CreateGraphicsPipelineState: When using tesselation, both the Hull Shader and Domain Shader must be set.  Otherwise, both must be NULL. [ STATE_CREATION ERROR #667: CREATEGRAPHICSPIPELINESTATE_HS_XOR_DS_MISMATCH]

Hull Shader

ハルシェーダは２つに分かれる。

１つは頂点データを設定するメイン関数。

もう１つは、分割の細かさを設定するパッチ定数関数。

頂点バッファをパッチという単位にして、１パッチ毎に呼ばれるのが定数関数で、パッチ＆頂点単位に呼ばれるのがメイン関数。

メイン関数定義

	[domain("quad")]
	[partitioning("integer")]
	[outputtopology("triangle_ccw")]
	[outputcontrolpoints(4)]
	[patchconstantfunc("CHSMain")]
	HSOutput HSMain( InputPatch<VSOutput, 4> IP, uint CP : SV_OutputControlPointID, uint PatchID : SV_PrimitiveID )
    {
      	HSOutput Out ;
		Out.Pos = IP[CP].Pos ;
		Out.UV = IP[CP].UV ;
      	return Out ;
    }

メイン関数の先頭で色々な設定をする。

domain

domainに設定できる値は、quad（四角形）、tri(三角形)、isoline(線分)の３つ。

この値が決まると、outputcontrolpointsと、関数の引数InputPachの第二引数と、IASetPrimitiveTopologyの引数が決まるっぽい。

"quad"の場合は４、TopologyはD3D_PRIMITIVE_TOPOLOGY_4_CONTROL_POINT_PATCHLIST。

"tri"の場合は３、TopologyはD3D_PRIMITIVE_TOPOLOGY_3_CONTROL_POINT_PATCHLIST。
"isoline"の場合は２、TopologyはD3D_PRIMITIVE_TOPOLOGY_2_CONTROL_POINT_PATCHLIST。

この法則を崩して別な呼び方もあるかもしれないけど、今のところこの呼び方だけ確認した。コントロールポイントの定義は32まである。

partitioning

partitioningに設定できる値、integer、fractional_even、fractional_odd、pow2。

分割時の係数を整数(integer、pow2)で見るのか、小数(fractional_even、fractional_odd)で見るのかの違いと、係数の最小値の違いがあったけど、integerとpow2の違いはよくわからなかった。

outputtopology

outputtopologyに設定できる値はpoint(点)、line(線)、triangle_cw(面：時計回り)、triangle_ccw(面：反時計回り)

点と線を作り出すパターンはよくわからず。

domainを"tri"にした場合は"triangle_cw"で、"quad"にした場合は"triangle_ccw"にしないと、元々の面と向きが反対になった。

outputcontrolpoints

出力するコントロールポイントの数。入力のコントロールポイントの数と異なっても良いらしいが、そのパターンは未確認。

patchconstantfunc

パッチ定数関数名を指定する。

引数

InputPatch<VSの出力構造体, 入力コントロールポイント数>

この引数が必須で後はSV_系の引数がオプションで使える。

使えるセマンティックはSV_PrimitiveIDとSV_OutputControlPointID。

コントロールポイントが３の場合、SV_PrimitiveIDとSV_OutputControlPointIDは、(0,0),(0,1)(0,2),(1,0),(1,1)(1,2)...という値を受け取る。

パッチ定数関数定義

	struct CHSOutput
	{
		float Edge[4]	: SV_TessFactor ;
		float Inside[2]	: SV_InsideTessFactor ;
	} ;
	CHSOutput CHSMain( InputPatch<VSOutput, 4> IP, uint PatchID : SV_PrimitiveID )
	{
		CHSOutput Out ;
		Out.Edge[0] = Out.Edge[1] = Out.Edge[2] = Out.Edge[3] = gHSParam.EdgeFactor ;
		Out.Inside[0] = Out.Inside[1] = gHSParam.InsideFactor ;
		return Out ;
	}

引数

InputPatch<VSの出力構造体, 入力コントロールポイント数>

メイン関数と同様の引数。それ以外のSV_系の引数はSV_PrimitiveIDが使える。

呼ばれる単位はパッチID単位なので、SV_OutputControlPointIDを指定するとコンパイルエラーになる。

戻り値

これは、メイン関数のdomainにより決まる。

"quad"にした場合

	float Edge[4]	: SV_TessFactor ;
	float Inside[2]	: SV_InsideTessFactor ;

分割係数を設定する際のヘルパ関数

ProcessTriTessFactorsAvg

ProcessTriTessFactorsMax

ProcessTriTessFactorsMin

"tri"にした場合

	float Edge[3]	: SV_TessFactor ;
	float Inside	: SV_InsideTessFactor ;

分割係数を設定する際のヘルパ関数

ProcessQuadTessFactorsAvg
ProcessQuadTessFactorsMax
ProcessQuadTessFactorsMin
Process2DQuadTessFactorsAvg
Process2DQuadTessFactorsMax
Process2DQuadTessFactorsMin

"isoline"にした場合

	float Edge[2]	: SV_TessFactor ;

分割係数を設定する際のヘルパ関数

ProcessIsolineTessFactors

試しにProcessQuadTessFactorsAvgを使ってみたけど、RawEdgeFactorsに各辺の分割数、InsideScaleに１を指定すると、RoundedInsideTessFactorsには各辺の分割数がそのまま返ってくる感じだった。各辺の分割数がバラバラの値を指定した時、平均に分割されたように見える値に調整してくれるのかな？

Domain Shader

[domain("quad")]
	DSOutput DSMain( CHSOutput In, const OutputPatch<HSOutput, 4> OP, float2 DL : SV_DomainLocation )
	{
		DSOutput Out ;
		float4 p1 = lerp( OP[1].Pos, OP[0].Pos, DL.x ) ;
		float4 p2 = lerp( OP[3].Pos, OP[2].Pos, DL.x ) ;
		Out.Pos = lerp( p1, p2, DL.y ) ;

		float2 t1 = lerp( OP[1].UV, OP[0].UV, DL.x ) ;
		float2 t2 = lerp( OP[3].UV, OP[2].UV, DL.x ) ;
		Out.UV = lerp( t1, t2, DL.y ) ;
		return Out ;
	}

引数

CHSOutput In

ハルシェーダのパッチ定数関数の出力型。

const OutputPatch<HSの出力構造体, 入力コントロールポイント数>

ハルシェーダの出力をOutputPatchで囲った型。

float2 DL : SV_DomainLocation

テッセレータの出力結果？

この引数もdomain設定により決まる。

"quad"にした場合float2、"tri"にした場合float3、"isoline"にした場合float2。

この値を元に、出力の頂点を補間する。

quadの動作結果

domainを"quad"、partitioningを"integer"で動作させた結果。

EdgeFactor、InsideFactor共に１を指定した場合、分割は行われず元のまま。

EdgeFactorを１ずつ上げていくとこの様に辺の部分が指定した分割数になる。

最大64分割まで可能で、それ以上の値を指定しても64分割となる。

整数なので、1.1と2も同じ扱いで、小数点以下は切り上げられるようだ。

InsideFactorを１ずつ上げていくとこの様に内側に四角が出来てくる。辺の場合は数えられたが、Insideの方はどこをどう数えればいいのか分からない。

最大64分割まで可能で、それ以上の値を指定しても64分割となる。

EdgeFactorとInsideFactor両方とも同じ様に上げていくと、全体がきれいな分割になる。

fractional_even

fractional_odd

integerをそれぞれ、fractional_even、fractional_oddに変えるとこの様になる。

fractional_evenの方は、EdgeFactorの最小値が2となり、１を指定しても２を指定してもこの形になる。２を超えたところから変化が始まる。

fractional_even

EdgeFactorのみ、InsideFactorのみ、EdgeFactorとInsideFactorの値を動かしたときの分割結果。

fractional_odd

EdgeFactorのみ、InsideFactorのみ、EdgeFactorとInsideFactorの値を動かしたときの分割結果。InsideFactorが1のままEdgeFactorを上昇させても変化しない為、EdgeFactorのみ上昇時はInsideFactorは２に設定。

triの動作結果

fractional_even

EdgeFactorのみ、InsideFactorのみ、EdgeFactorとInsideFactorの値を動かしたときの分割結果。

fractional_odd

EdgeFactorのみ、InsideFactorのみ、EdgeFactorとInsideFactorの値を動かしたときの分割結果。InsideFactorが1のままEdgeFactorを上昇させても変化しない為、EdgeFactorのみ上昇時はInsideFactorは２に設定。

今回の嵌まりポイント

ハルシェーダのパッチ定数関数を定義して、patchconstantfuncでも指定しているにも関わらず、コンパイルエラーで定義されていないと言われ続けた。

関数の引数は構造体で定義して１つだけにしてスッキリさせていたんだけど、ハルシェーダとドメインシェーダの場合どうやら対応してないみたいで、引数にInputPatch、OutputPatchの引数があることが条件になっているのかもしれない。

サンプルの通り引数を並べてみたらコンパイルが通った。